Как я могу отобразить новую строку в пакетном файле?

echo hello & echo.world

Это означает, что вы можете определить & echo. как константу для новой строки \n.

Использовать:

echo hello
echo.
echo world

Итак, создайте файл .bat со следующим содержимым:

@echo off
REM Creating a Newline variable (the two blank lines are required!)
set NLM=^


set NL=^^^%NLM%%NLM%^%NLM%%NLM%
REM Example Usage:
echo There should be a newline%NL%inserted here.

echo.
pause

Вы должны увидеть следующий результат:

There should be a newline
inserted here.

Press any key to continue . . .

Очевидно, вам нужен только код между операторами REM.

В cmd / bat-файлах есть стандартная функция echo: для записи пустой строки, которая имитирует новую строку в вашем cmd-выводе:

@echo off
@echo line1
@echo:
@echo line2

Вывод указанного cmd-файла:

line1

line2

Как и ответ Кена, но с использованием отложенного расширения.

setlocal EnableDelayedExpansion
(set \n=^
%=Do not remove this line=%
)

echo Line1!\n!Line2
echo Works also with quotes "!\n!line2"

Сначала создается одиночный символ перевода строки, который назначается переменной \ n.
Это работает, когда курсор в конце строки пытается экранировать следующий символ, но если это перевод строки, он игнорируется и считывается следующий символ. и экранированы (даже если это также перевод строки).
Тогда вам понадобится третий перевод строки, чтобы завершить текущую инструкцию, иначе третья строка будет добавлена ​​к LF-переменной.
Даже в пакетных файлах строки заканчиваются на CR / LF важны только LF, так как CR удаляются на этой фазе синтаксического анализа.

Преимущество использования отложенного раскрытия заключается в том, что здесь вообще нет специальной обработки символов.
echo Line1%LF%Line2 завершится ошибкой, поскольку синтаксический анализатор прекращает синтаксический анализ при одиночных переводах строки.

Дополнительные объяснения находятся на странице
ТАК: длинные команды разделены на несколько строк в пакетном файле Vista / DOS (.bat)
ИСТОЧНИК: Как интерпретатор команд Windows (CMD.EXE) анализирует сценарии?

Изменить: избегать echo.

Это не отвечает на вопрос, поскольку вопрос касался одного echo, который может выводить несколько строк.

Но, несмотря на другие ответы, которые предлагают использовать echo. для создания новой строки, следует отметить, что echo. является худшим, поскольку он очень медленный и может полностью выйти из строя, поскольку cmd.exe ищет файл с именем ECHO и пытается Начни это.

Для печати пустой строки вы можете использовать одну из

echo,
echo;
echo(
echo/
echo+
echo=

Но следует избегать использования echo., echo\ или echo:, поскольку они могут быть очень медленными, в зависимости от места, где будет выполняться сценарий, например, сетевой диск.

echo. Достаточно сказано.

Если он вам нужен в одной строке, используйте &. Например,

echo Line 1 & echo. & echo line 3

будет выводиться как:

Line 1

line 3

Теперь предположим, что вы хотите чего-то более красивого, ...

set n=^&echo.
echo hello %n% world

Выходы

hello
world

Затем просто вставляйте %n% всякий раз, когда вам нужна новая строка в операторе echo. Это больше похоже на ваш \n, используемый на разных языках.

Разбивка

set n= устанавливает переменную n равной:

^ Обнуляет следующий за ним символ:

& Означает выполнить другую команду в той же строке. Мы не заботимся об уровне ошибок (это эхо-оператор для громкого крика), поэтому && не требуется.

echo. Продолжает эхо-запрос.

Все это работает, потому что вы можете создавать переменные в виде кода и использовать их внутри других команд. Это что-то вроде функции гетто, поскольку пакетная обработка - не самый продвинутый из языков сценариев оболочки. Это работает только из-за плохого использования переменных в пакете, естественного отсутствия обозначения между целыми числами, символами, числами с плавающей запятой, строками и т. Д.

Если вы изобретательны, вы можете заставить это работать с другими вещами. Например, используя его для вывода табуляции

set t=^&echo.     ::there are spaces up to the double colon

При отображении чего-либо для перенаправления в файл несколько команд эха не будут работать. Думаю, редиректор ">>" - хороший выбор:

echo hello > temp
echo world >> temp

Если вам нужно поместить результаты в файл, вы можете использовать

(echo a & echo. & echo b) > file_containing_multiple_lines.txt

Как и предлагает Гримтрон - вот краткий пример, чтобы определить это:

@echo off
set newline=^& echo.
echo hello %newline%world

Выход

C:\>test.bat
hello
world

Вы также можете сделать это,

(for %i in (a b "c d") do @echo %~i)

Выход будет,

a
b
c d

Обратите внимание, что когда это помещается в пакетный файл, "%" должен быть удвоен.

(for %%i in (a b "c d") do @echo %%~i)

Если кто-то приходит сюда, потому что хочет повторить пустую строку из make-файла MINGW, я использовал

@cmd /c echo.

простое использование echo. вызывает ужасное сообщение об ошибке process_begin: CreateProcess(NULL, echo., ...) failed..

Надеюсь, это поможет хотя бы еще одному человеку :)

Чтобы начать новую строку в пакете, все, что вам нужно сделать, это добавить «echo [», например:

echo Hi!
echo[
echo Hello!

Решения Кена и Джеба работают хорошо.

Но новые строки создаются только с помощью символа LF, а мне нужны символы CRLF (версия для Windows).

Для этого в конце сценария я преобразовал LF в CRLF.

Пример:

TYPE file.txt | FIND "" /V > file_win.txt
del file.txt
rename file_win.txt file.txt

Если нужно использовать знаменитый \ n в строковых литералах, которые могут быть переданы в переменную, можно написать код, как в сценарии Hello.bat ниже:

@echo off
set input=%1
if defined input (
    set answer=Hi!\nWhy did you call me a %input%?
) else (
    set answer=Hi!\nHow are you?\nWe are friends, you know?\nYou can call me by name.
)

setlocal enableDelayedExpansion
set newline=^


rem Two empty lines above are essential
echo %answer:\n=!newline!%

Таким образом, многострочный вывод может быть подготовлен в одном месте, даже в другом сценарии или внешнем файле, и распечатан в другом.

Разрыв строки сохраняется в переменной новой строки. Его значение должно быть заменено после расширения строки echo, поэтому я использую setlocal enableDelayedExpansion, чтобы включить восклицательные знаки, которые расширяют переменные при выполнении. И выполнение заменяет \ n содержимым новой строки (синтаксис ищите в наборе справки). Конечно, мы могли бы использовать ! Newline! при установке ответа, но \ n более удобно. Его можно передать извне (попробуйте Hello R2 \ nD2), где никто не знает имя переменной, содержащей разрыв строки (Да, Hello C3! Newline! P0 работает с так же).

Приведенный выше пример может быть преобразован в подпрограмму или автономный пакет, используемый как call:mlecho Hi\nI'm your comuter:

:mlecho
setlocal enableDelayedExpansion
set text=%*
set nl=^


echo %text:\n=!nl!%
goto:eof

Обратите внимание, что дополнительная обратная косая черта не помешает скрипту проанализировать подстроку \ n.

Это сработало для меня, без необходимости отложенного расширения:

@echo off
(
echo ^<html^> 
echo ^<body^>
echo Hello
echo ^</body^>
echo ^</html^>
)
pause

Он записывает вывод следующим образом:

<html>
<body>
Hello
</body>
</html>
Press any key to continue . . .

Для Windows 10 с последовательностями виртуальных терминалов там существуют средства управления положением курсора в высокой степени.

Чтобы определить escape-последовательность 0x1b, можно использовать следующее:

@Echo off
 For /f %%a in ('echo prompt $E^| cmd')Do set \E=%%a

Чтобы вывести одну новую строку между строками:

<nul set /p "=Hello%\E%[EWorld"

Для вывода n новой строки, где n заменяется целым числом:

<nul set /p "=%\E%[nE"

Много

Вы можете использовать @echo (@echo + [пробел] + [незащищенное пространство])

Примечание: незащищенное пространство можно получить с помощью Alt + 0160.

Надеюсь, это поможет :)

[править] Хм, вы правы, мне это нужно в Makefile, там он отлично работает. Думаю, мой ответ не адаптирован для командных файлов ... Моя плохая.

просто

set nl=.
echo hello
echo%nl%
REM without space ^^^
echo World

Результат:

hello
world

почему бы не использовать подстроку / заменить пробел на echo;?

set "_line=hello world"
echo\%_line: =&echo;%

• Полученные результаты:

hello
world

• Или замените \ n на echo;

set "_line=hello\nworld"
echo\%_line:\n=&echo;%

Это решение работает (протестировано):

type nul | more /e /p

Это преобразует изолированные переводы строки в комбинацию перевода строки возврата каретки.